Text Extract - 2

I know you're looking for a PQ or legacy solution but I'd handle this with a Lambda.  The Lambda created is portable and can be moved to any workbook where needed.

SignalSplitλ = LAMBDA(table_col,
        LET(
        //Assign header
            header, {
                "MeasQuantityResults-CellIdentity","rsrp","rsrq","sinr","",
                "ssbIndex","rsrp","rsrq","sinr"},
        //Wrap vector - 1 record = 19 rows
            wrapped, WRAPROWS(table_col, 19, ""),
        //Concat and covert back to vector
            joined, BYROW(wrapped, CONCAT),
        //Remove double quotes to simplify extraction
            cleaned, SUBSTITUTE(joined, """", ""),
        //Function to extract text between two delimiters
            TextBetweenλ, LAMBDA(texts, after_delim, before_delim,
                TEXTBEFORE(TEXTAFTER(texts, after_delim, , , , ""), before_delim, , , , "")
            ),
        //Extract text between delimiters:
            cell_identity, TextBetweenλ(cleaned, "310/260-", ","),
            rsrp, TextBetweenλ(cleaned, "rsrp: ", ","),
            rsrq, TextBetweenλ(cleaned, "rsrq: ", ","),
            sinr, TextBetweenλ(cleaned, "sinr: ", " }"),
            ssb_index, TextBetweenλ(cleaned, "ssbIndex: ", ","),
        //"Space" vector to be added in middle of return matrix
            space, EXPAND("", ROWS(rsrp), , ""),
        //Stack columns
            return, VSTACK(
                header,
                HSTACK(cell_identity, rsrp, rsrq, sinr, space, ssb_index, rsrp, rsrq, sinr)
            ),
            return
        )
    );

At the sheet level the formula is:

The uploaded workbook doesn't contain the embedded .txt file.  Is the text sample from JSON?